**ALFA Programming Language Grammar**

|  |  |  |  |
| --- | --- | --- | --- |
| 1 | <programa> | ::= | **main {** <declaraciones> <funciones> <sentencias> **}** |
| 2 | <declaraciones> | ::= | <declaracion> |
| 3 |  | | | <declaracion> <declaraciones> |
| 4 | <declaracion> | ::= | <clase> <identificadores> **;** |
| 5 | <clase> | ::= | <clase\_escalar> |
| 6 |  | | | <clase\_puntero> |
| 7 |  | | | <clase\_vector> |
| 8 |  | | | <clase\_conjunto> |
| 9 | <clase\_escalar> | ::= | <tipo> |
| 10 | <tipo> | ::= | **int** |
| 11 |  | | | **boolean** |
| 12 |  | | | **float** |
| 13 | <clase\_puntero> | ::= | <tipo> **\*** |
| 14 |  | | | <clase\_puntero> **\*** |
| 15 | <clase\_vector> | ::= | **array** <tipo> **[** <constante\_entera> **]** |
| 16 |  | | | **array** <tipo> **[** <constante\_entera> **,** <constante\_entera> **]** |
| 17 | <clase\_conjunto> | ::= | **set of** <constante\_entera> |
| 18 | <identificadores> | ::= | <identificador> |
| 19 |  | | | <identificador> **,** <identificadores> |
| 20 | <funciones> | ::= | <funcion> <funciones> |
| 21 |  | | |  |
| 22 | <funcion> | ::= | **function** <tipo> <identificador> **(** <parametros\_funcion> **) {** <declaraciones\_funcion> <sentencias> **}** |
| 23 | <parametros\_funcion> | ::= | <parametro\_funcion> <resto\_parametros\_funcion> |
| 24 |  | | |  |
| 25 | <resto\_parametros\_funcion> | ::= | **;** <parametro\_funcion> <resto\_parametros\_funcion> |
| 26 |  | | |  |
| 27 | <parametro\_funcion> | ::= | <tipo> <identificador> |
| 28 | <declaraciones\_funcion> | ::= | <declaraciones> |
| 29 |  | | |  |
| 30 | <sentencias> | ::= | <sentencia> |
| 31 |  | | | <sentencia> <sentencias> |
| 32 | <sentencia> | ::= | <sentencia\_simple> **;** |
| 33 |  | | | <bloque> |
| 34 | <sentencia\_simple> | ::= | <asignacion> |
| 35 |  | | | <lectura> |
| 36 |  | | | <escritura> |
| 37 |  | | | <liberacion> |
| 38 |  | | | <retorno\_funcion> |
| 39 |  | | | <operacion\_conjunto> |
| 40 | <bloque> | ::= | <condicional> |
| 41 |  | | | <bucle> |
| 42 |  | | | <seleccion> |
| 43 | <asignacion> | ::= | <identificador> **=** <exp> |
| 44 |  | | | <elemento\_vector> **=** <exp> |
| 45 |  | | | <acceso> **=** <exp> |
| 46 |  | | | <identificador> **=** **malloc** |
| 47 |  | | | <identificador> **=** **&** <identificador> |
| 48 | <elemento\_vector> | ::= | <identificador> **[** <exp> **]** |
| 49 |  | | | <identificador> **[** <exp> **,** <exp> **]** |
| 50 | <condicional> | ::= | **if (** <exp> **)** **{** <sentencias> **}** |
| 51 |  | | | **if (** <exp> **)** **{** <sentencias> **} else {** <sentencias> **}** |
| 52 | <bucle> | ::= | **while (** <exp> **) {** <sentencias> **}** |
| 53 |  | | | **for (**<identificador> **=** <exp> **;** <exp> **) {** <sentencias> **}** |
| 54 | <lectura> | ::= | **scanf** <identificador> |
| 55 |  | | | **scanf** <elemento\_vector> |
| 56 | <escritura> | ::= | **printf** <exp> |
| 57 |  | | | **cprintf** <identificador> |
| 58 | <liberacion> | ::= | **free** <identificador> |
| 59 | <acceso> | ::= | **\*** <identificador> |
| 60 |  | | | **\*** <acceso> |
| 61 | <retorno\_funcion> | ::= | **return** <exp> |
| 62 | <seleccion> | ::= | **switch** **(** <exp> **)** **{** <casos\_seleccion> **}** |
| 63 | <casos\_seleccion> | ::= | <casos\_estandar> <caso\_defecto> |
| 64 | <casos\_estandar> | ::= | <caso\_estandar> |
| 65 |  | | | <casos\_estandar> <caso\_estandar> |
| 66 | <caso\_estandar> | ::= | **case** <constante\_entera> **:** <sentencias> |
| 67 | <caso\_defecto> | ::= | **default** <sentencias> |
| 68 | <operacion\_conjunto> | ::= | **union (** <identificador> **,**<identificador> **,** <identificador> **)** |
| 69 |  | | | **intersection (** <identificador> **,** <identificador> **,** <identificador> **)** |
| 70 |  | | | **add (** <exp> **,** <identificador> **)** |
| 71 |  | | | **clear (** <identificador> **)** |
| 72 | <exp> | ::= | <exp> **+** <exp> |
| 73 |  | | | <exp> **-** <exp> |
| 74 |  | | | <exp> **/** <exp> |
| 75 |  | | | <exp> **\*** <exp> |
| 76 |  | | | **-** <exp> |
| 77 |  | | | <exp> **&&** <exp> |
| 78 |  | | | <exp> **||** <exp> |
| 79 |  | | | **!** <exp> |
| 80 |  | | | <identificador> |
| 81 |  | | | <constante> |
| 82 |  | | | **(** <exp> **)** |
| 83 |  | | | **(** <comparacion> **)** |
| 84 |  | | | <acceso> |
| 85 |  | | | <elemento\_vector> |
| 86 |  | | | **size** **(** <identificador> **)** |
| 87 |  | | | **contains (** <exp> **,** <identificador> **)** |
| 88 |  | | | <identificador> **(** <lista\_expresiones> **)** |
| 89 | <lista\_expresiones> | ::= | <exp> <resto\_lista\_expresiones> |
| 90 |  | | |  |
| 91 | <resto\_lista\_expresiones> | ::= | **,** <exp> <resto\_lista\_expresiones> |
| 92 |  | | |  |
| 93 | <comparacion> | ::= | <exp> **==** <exp> |
| 94 |  | | | <exp> **!=** <exp> |
| 95 |  | | | <exp> **<=** <exp> |
| 96 |  | | | <exp> **>=** <exp> |
| 97 |  | | | <exp> **<** <exp> |
| 98 |  | | | <exp> **>** <exp> |
| 99 | <constante> | ::= | <constante\_logica> |
| 100 |  | | | <constante\_entera> |
| 101 |  | | | <constante\_real> |
| 102 | <constante\_logica> | ::= | **true** |
| 103 |  | | | **false** |
| 104 | <constante\_entera> | ::= | <numero> |
| 105 | <numero> | ::= | <digito> |
| 106 |  | | | <numero> <digito> |
| 107 | <constante\_real> | ::= | <constante\_entera> **.** <constante\_entera> |
| 108 | <identificador> | ::= | <letra> |
| 109 |  | | | <letra> <cola\_identificador> |
| 110 | <cola\_identificador> | ::= | <alfanumerico> |
| 111 |  | | | <alfanumerico> <cola\_identificador> |
| 112 | <alfanumerico> | ::= | <letra> |
| 113 |  | | | <digito> |
| 114 | <letra> | ::= | **a** | **b** | ... | **z** | **A** | **B** |...| **Z** |
| 115 | <digito> | ::= | **0** | **1** | **2** | **3** | **4** | **5** | **6** | **7** | **8** | **9** |

**Additional considerations**

* The language allows to include comments between the characters of // and the end of line (they are one-line comments).
* Identifiers length is limited to 100 characters.

**Only the productions highlighted in grey are going to be used in the compiler for this course**